IFTTT를 통하여 메일 보내기

// AP_SSID를 3개까지 지정할 수 있음
#define AP_SSID1  "ssid1"
#define AP_PASS1  "pass1"

#define AP_SSID2  "ssid2"
#define AP_PASS2  "pass2"

#define AP_SSID3  "ssid3"
#define AP_PASS3  "pass3"

// SSID 개수 임의로 지정 가능(AP_SSID1말고 직접 지정해도 됨)
const char* ssid[] = {AP_SSID1,AP_SSID2,AP_SSID3};
const char* pass[] = {AP_PASS1,AP_PASS2,AP_PASS3};

#include <AimWiFi.h>
AimWiFi wifi;

// http 방식으로 접속하기 위함 
#if defined(ESP8266)
#include <ESP8266HTTPClient.h>
#elif defined(ESP32)
#include <HTTPClient.h>
#endif

// IFTTT webhook (https는 http로 바꾸어야함)
String event = "email";
String key = "btXtk3RpXXXXX4X7_07eFY";
String url = "http://maker.ifttt.com/trigger/{event}/with/key/{key}";

// 60 마다 연결 
#include <AimTimer.h>
AimTimer timerPost(60);

// JSON 형식의 데이터 처리 
#include <ArduinoJson.h>

void setup(void) {
  Serial.begin(115200);
  Serial.println();
  wifi.begin(ssid,pass,sizeof(ssid));
  timerPost.nowOn();

  // webhook URL 완성만들기  
  url.replace("{event}",event);
  url.replace("{key}",key);
}

void loop() {
  if (timerPost.isOn()) {
  	postToIFTTT();
  }
}

void postToIFTTT() {	
	
	// 인터넷 사이트에 접속하기 위하여 http 생성 
	HTTPClient http;

  // 인터넷 사이트에 접속
	http.begin(url);

	// JSON형식의 데이터 보냄
	http.addHeader("Content-Type","application/json");

	// JSON 형식으로 데이터 만듬
  String value1 = String(millis()/1000);
  String value2 = "두 번째 값";
  String value3 = "세 번째 값";
	String json = makeJson(value1,value2,value3);

	// 인터넷 사이트에서 데이터 받아오기 위하여 접속 시도  
	int httpCode = http.POST(json);
  
	// 인터넷 사이트에 접속이 되면 
	if (httpCode > 0 ) {
	  // 인터넷 사이트에서 처리 결과 메시지를 받아옴 
	  String payload = http.getString();
	  Serial.println("webhook return :"+payload);
	}
	else {
		Serial.printf("httpCode=%d\n",httpCode);
	}
	
	// 접속을 종료함 
	http.end();	
}

String makeJson(String v1,String v2,String v3) {
	
	// Prepare JSON document : 메모리에 JSON 표현
  DynamicJsonDocument doc(2048);
  doc["value1"] = v1;
  doc["value2"] = v2;
  doc["value3"] = v3;

  // Serialize JSON document : {} 텍스트 형식 
  String json;
  serializeJson(doc, json);
  Serial.println(json);
  return json;
}

// AP_SSID를 3개까지 지정할 수 있음
#define AP_SSID1  "ssid1"
#define AP_PASS1  "pass1"

#define AP_SSID2  "ssid2"
#define AP_PASS2  "pass2"

#define AP_SSID3  "ssid3"
#define AP_PASS3  "pass3"

// SSID 개수 임의로 지정 가능(AP_SSID1말고 직접 지정해도 됨)
const char* ssid[] = {AP_SSID1,AP_SSID2,AP_SSID3};
const char* pass[] = {AP_PASS1,AP_PASS2,AP_PASS3};

#include <AimWiFi.h>
AimWiFi wifi;

#include <Aims_ifttt.h>
Aims_ifttt ifttt;

String event = "email";
String key = "btXtk3RpXXXXX4X7_07eFY";

// 60 마다 연결 
#include <AimTimer.h>
AimTimer timerPost(60);

void setup(void) {
  Serial.begin(115200);
  Serial.println();
  
  wifi.begin(ssid,pass,sizeof(ssid));
  timerPost.nowOn();
}

void loop() {
  if (timerPost.isOn()) {
  	String value1 = String(millis()/1000);
  	String value2 = "두 번째 값";
  	String value3 = "세 번째 값";
  	int httpCode = ifttt.send(event,key,value1,value2,value3);
  	if (httpCode > 0) {
      Serial.printf("value1:[%s],value2:[%s],value3:[%s]\n",value1.c_str(),value2.c_str(),value3.c_str());
  	  Serial.println(ifttt.getString());
  	}
  }
}