외부 웹서버에 접속하여 정보 교환하기

// AP_SSID를 3개까지 지정할 수 있음
#define AP_SSID1  "ap_ssid1"
#define AP_PASS1  "ap_pass1"

#define AP_SSID2  "ap_ssid2"
#define AP_PASS2  "ap_pass2"

#define AP_SSID3  "ap_ssid3"
#define AP_PASS3  "ap_pass3"

// SSID 개수 임의로 지정 가능(AP_SSID1말고 직접 지정해도 됨)
const char* ssid[] = {AP_SSID1,AP_SSID2,AP_SSID3};
const char* pass[] = {AP_PASS1,AP_PASS2,AP_PASS3};

#include <AimWiFi.h>
AimWiFi wifi;

// http 방식으로 접속하기 위함 
#include <ESP8266HTTPClient.h>

// 지역별 날씨 예보 정보를 돌려주는 RSS임 
const char* URL    = "/wid/queryDFSRSS.jsp?zone=1171065000";
const char* SERVER = "www.kma.go.kr";
//www.kma.go.kr/wid/queryDFSRSS.jsp?zone=1171065000

#include <AimTimer.h>
AimTimer timerWeather(10);

// XML 형식의 데이터를 돌려줌 
#include <AimGetXml.h>

void setup(void) {
  Serial.begin(115200);
  Serial.println();
  wifi.begin(ssid,pass,sizeof(ssid));
  timerWeather.nowOn();
}

void loop() {
  if (timerWeather.isOn()) {
  	getWeather();
  }
}

void getWeather() {	
	
	// 인터넷 사이트에 접속하기 위하여 http 생성 
	HTTPClient http;

    // URL 만들기
	String url = String("http://") + SERVER +URL;	

	// 인터넷 사이트에 접속
	http.begin(url);

	// 인터넷 사이트에서 데이터 받아오기 위하여 접속 시도  
	int httpCode = http.GET();
    
	// 인터넷 사이트에 접속이 되면 
	if (httpCode > 0 ) {

	  // 인터넷 사이트에서 데이터를 받아옴 
	  String payload = http.getString();

	  // <tm>202007210200</TM> 사이의 값 가져옴
	  String tm    = AimGetXml(payload,"tm");

	  String temp  = AimGetXml(payload,"temp");
	  String wfEn  = AimGetXml(payload,"wfEn");
	  String wfKor = AimGetXml(payload,"wfKor");
	  String reh   = AimGetXml(payload,"reh");
	  Serial.println("Date time:"+tm);
	  Serial.println("Temperature:"+temp);
	  Serial.println("Humidity :"+reh);
	  Serial.println("Cloudy:"+wfEn);
	  Serial.println("구름:"+wfKor);
	  Serial.println();
	}
	else {
		Serial.printf("httpCode=%d\n",httpCode);
	}
	// 접속을 종료함 
	http.end();	
}

Connecting to [ap_ssid1],[ap_ssid2],[ap_ssid3]
.....
Connected to [ap_ssid1],IP=192.168.35.246
Date time:202007210200
Temperature:23.0
Humidity :85
Cloudy:Mostly Cloudy
구름:구름 많음